Generalized Extreme Value Distribution

The generalized extreme value distribution in standardized form is given below.

(e^(-(((1 + x ξ))^(-1/ξ)))); where 1 + x ξ > 0.

This function has a limit at ξ = 0, so it is continuous over the entire range of ξ.

(lim_(ξ->0)) (e^(-(((x ξ+1))^(-1/ξ))))  = (e^(-(e^(-x))))

A three parameter form of the distribution is needed for fitting, where μ is the location parameter and σ > 0 is the scale parameter, by substituting.

x->((x-μ)/σ)

The full parameterization of the distribution function :

GEV(x,ξ,σ,μ) = (e^(-((((((x-μ) ξ)/σ)+1))^(-1/ξ)))) ;  where (((x-μ) ξ)/σ)+1>0 and ξ≠0and σ>0 
GEV(x,ξ,σ,μ) = (e^(-(e^((μ-x)/σ))))                                       ;  where ξ= 0and σ>0

The density function is.

gev(x,ξ,σ,μ)=(((e^(-((((((x-μ) ξ)/σ)+1))^(-1/ξ)))) ((((((x-μ) ξ)/σ)+1))^(-1-(1/ξ))))/σ)  ; where (((x-μ) ξ)/σ)+1>0and ξ≠0and σ>0
gev(x,ξ,σ,μ)=((e^(((μ-x)/σ)-(e^((μ-x)/σ))))/σ)                                                          ;  where ξ== 0and σ>0

For maximum likelihood fitting, the corresponding log densities have an explicit form with the same corresponding parameter restrictions:

loggev(x,ξ,σ,μ)=-((((((x-μ) ξ)/σ)+1))^(-1/ξ))-log(σ)-(((ξ+1) log((((x-μ) ξ)/σ)+1))/ξ)  
loggev(x,ξ,σ,μ)=-((x-μ)/σ) -(e^((μ-x)/σ))  - log(σ)

The plots of the density and distribution functions are shown below for the standardized distributions (σ = 1, μ = 0).  Note that the right tail of the yellow curve is abruptly truncated at x = 2.

GEV[x_,ξ_,σ_,μ_]:=Piecewise[{{(E^(-(((1+(((-μ+x) ξ)/σ)))^(-1/ξ)))),ξ≠0&&x ξ+σ>μ ξ},{(E^(-(E^((-x+μ)/σ)))),ξ==0&&σ>0}}];
gev[x_,ξ_,σ_,μ_]:=(Piecewise[{{(((E^(-(((1+(((x-μ) ξ)/σ)))^(-1/ξ)))) (((1+(((x-μ) ξ)/σ)))^(-1-(1/ξ))))/σ), ξ≠0&&x ξ-μ ξ+σ>0}, {((E^(-(E^((-x+μ)/σ))+((-x+μ)/σ)))/σ), ξ==0&&σ>0}}]);
loggev[x_,ξ_,σ_,μ_]:= Piecewise[{{-(((1+(((x-μ) ξ)/σ)))^(-1/ξ))-(((1+ξ) Log[1+(((x-μ) ξ)/σ)])/ξ)-Log[σ],ξ≠0&&x ξ+σ>μ ξ},{-(E^((-x+μ)/σ))-((x-μ)/σ)-Log[σ],ξ==0&&σ>0}}];
SetAttributes[loggev,Listable];

g10=Plot[{GEV[x,0.5,1,0],GEV[x,0,1,0]},{x,-2,5} ];
g20=Plot[If[x<2,GEV[x,-0.5,1,0],1],{x,-3,5},PlotStyle->Darker[Yellow]];

g11=Plot[{gev[x,0.5,1,0],gev[x,0,1,0]},{x,-2,5} ];
g21=Plot[gev[x,-0.5,1,0],{x,-3,2},PlotStyle->Darker[Yellow]];
GraphicsRow[{Show[g11,g21,PlotRange->All],Show[g10,g20,PlotRange->All]},PlotLabel-> "Blue  ξ = 0.5\nRed   ξ = 0\nYellow   ξ = -0.5"]

These distributions form the limiting distributions of maximum or minimum values of a set of random variables from a stationary distribution.  The convergence is analogous to the convergence of sums of random variables by the generalized central limit theorem.  The maximum, (Subscript[M, n]), of a set of random variables is defined below.

(Subscript[M, n])=Maximum( {(Subscript[X, 1]),(Subscript[X, 2]),(Subscript[X, 3]),...,(Subscript[X, n])})

For a minimum, (Subscript[M, n]), of a set the definition would be as shown below so the result would also be skewed positively.

(Subscript[M, n])=Maximum( {-(Subscript[X, 1]),-(Subscript[X, 2]),-(Subscript[X, 3]),...,-(Subscript[X, n])})

With this definition in mind if,

Pr((Subscript[M, n])≤x)=(F^n)(x)

then the limiting distribution for appropriately shifted and scaled x would be

(lim_(n->∞)) (F^n)[((x-μ)/σ)]

For example assume the primary distribution is an exponential distribution with the distribution function,

1-(e^(-x β)) ,

where x is appropriately scaled and shifted,

x->(x/β)+((log(n))/β),

(lim_(n->∞)) (((1-((e^(-x))/n)))^n) = (e^(-(e^(-x)))).

CDF[ExponentialDistribution[β],x]
TrigToExp[FullSimplify[1-(E^(-x β))/. x-> x/β +Log[n]/β]]
Limit[(1-((E^(-x))/n))^n,n->∞]

We conclude that the limiting distribution for maxima of an exponential distribution has the form of the extreme value distribution such that ξ = 0.  The normal distribution and lognormal distributions also have extreme value distributions with ξ = 0, but since the lognormal distribution has a heavier tail it will require larger n to show convergence.

Next we take the case of the Pareto distribution function for x,

({{1-((((k/x)))^α),, x>k}})

We scale and shift by

x->k (n^(1/α))+((x (k (n^(1/α))))/α)

(lim_(n->∞)) (((1-(((α^α) (((x+α))^(-α)))/n)))^n) = (e^(-(((((x+α)/α)))^(-α))));

We conclude the extreme value distribution has the form, ξ=(1/α).  Since stable distributions, with 0 < α < 2, and β ≠ ± 1, have asymptotically Pareto tails, we expect them to also converge to a generalized extreme value distribution with ξ = (1/α).

CDF[ParetoDistribution[k , α],x]
1-((((k/x)))^α)/.x-> x(k n^(1/α)/α)+ k n^(1/α)
PowerExpand[FullSimplify[%]]
Limit[(1-(( ((((x+α)/α))^(-α)))/n))^n,n->∞]

For further discussion of classes of extreme value distributions see:
McNeil, A.J., Frey, R., Embrechts, P. Quantitative Risk Management, Concepts, Techniques, Tools, Princeton University Press 2005, Chapter 7.

txcolor=RGBColor[181/255,18/255,27/255];
t1 = Graphics[Text[Hyperlink[Framed[Style["Financial Home", {txcolor, Bold, Larger}]], "../map/Overview.html"], {-5, 0}]];
t2 = Graphics[Text[Hyperlink[Framed[Style["Model Test", {txcolor, Bold, Larger}]],  "../s13/ModelTest.html"], {0, 0}]];
t3 = Graphics[Text[Hyperlink[Framed[Style["Download Notebook", {txcolor, Bold, Larger}]], "../s12/GeneralizedExtremeValueDistribution.nb"], {5, 0}]];
(*t4 = Graphics[Text[Hyperlink[Framed[Style["Previous", {txcolor, Bold, Larger}]], "../s10/LNStableRV.html"], {0, 0.5}]];*)

Show[ t1, t2, t3, ImageSize -> 500]
CellPrint[TextCell["\n\n© Copyright " <>ToString[DateList[][[1]]]<>" mathestate    "<>DateString[DateList[],"DateShort"], "Text"]]

© Copyright 2008 mathestate    Fri 10 Oct 2008