Properties of the Log Normally Scaled Stable Distribution

(*****************************************************)(*This notebook is not yet implemented in the StableM*)
(*free software. The implementation uses John Nolan's*)
(*STABLE software available at www.robustanalysis.com*)
(*If you would like algorithms for StableM which are*)
(*much slower, contact mathestate@gmail.com *)
(*****************************************************)
Needs["Stable`"];

Clear[LNStablePDF,LNQkStablePDF,LNStableRV,LNStableCDF,LNQkStableCDF];

stablepdf[x_?NumericQ,a_,b_:0,iparam_Integer:1]:=StablePDF[x,a,b,1,0,iparam];

LNStablePDF[x_?NumericQ,α_,β_:0,γ_:1,σ_,δ_:0,iparam_Integer:1]:= 1/((Sqrt[2 π])  σ)NIntegrate[((E^(-(((Log[(s/γ)])^2)/(2 (σ^2)))))/( s )) stablepdf[(x-δ)/s,α,β,iparam]/s ,{s,0,∞},Method->{Automatic,"SymbolicProcessing"->0}];
stableqkpdf[x_?NumericQ,a_,b_:0,iparam_Integer:1]:=StableQkPDF[x,a,b,1,0,iparam];

LNQkStablePDF[x_?NumericQ,α_,β_:0,γ_:1,σ_,δ_:0,iparam_Integer:1]:= 1/((Sqrt[2 π])  σ)NIntegrate[((E^(-(((Log[(s/γ)])^2)/(2 (σ^2)))))/( s )) stableqkpdf[(x-δ)/s,α,β,iparam]/s ,{s,0,∞},Method->{Automatic,"SymbolicProcessing"->0}];
LNStableRV[n_,α_,β_:0,γ_:1,σ_,δ_:0,iparam_Integer:1]:= RandomReal[LogNormalDistribution[Log[γ],σ],n] StableRandom[n,α,β,1,0,iparam]+δ;

stablecdf[x_?NumericQ,a_,b_:0,iparam_Integer:1]:=StableCDF[x,a,b,1,0,iparam];

LNStableCDF[x_?NumericQ,α_,β_:0,γ_:1,σ_,δ_:0,iparam_Integer:1]:= 1/((Sqrt[2 π])  σ)NIntegrate[((E^(-(((Log[(s/γ)])^2)/(2 (σ^2)))))/( s )) stablecdf[(x-δ)/s,α,β,iparam] ,{s,0,∞},Method->{Automatic,"SymbolicProcessing"->0}];
stableqkcdf[x_?NumericQ,a_,b_:0,iparam_Integer:1]:=StableQkCDF[x,a,b,1,0,iparam];

LNQkStableCDF[x_?NumericQ,α_,β_:0,γ_:1,σ_,δ_:0,iparam_Integer:1]:= 1/((Sqrt[2 π])  σ)NIntegrate[((E^(-(((Log[(s/γ)])^2)/(2 (σ^2)))))/( s )) stableqkcdf[(x-δ)/s,α,β,iparam]/s ,{s,0,∞},Method->{Automatic,"SymbolicProcessing"->0}];

On the previous page, we showed that the lognormally scaled stable  (LNS) distribution could be simulated with the product of a standardized stable random variable and a lognormal random variable.  The LNS distribution is more properly thought of as a mixture distribution (Feller, Vol. 2, p. 53) with the scale parameter, γ, having a lognormal distribution.  It can be calculated as follows.

Let λ (x, μ, σ) be the lognormal density function.

λ(x,μ,σ)=((e^(-((((log(x)-μ))^2)/(2 (σ^2)))))/((Sqrt[2 π]) x σ));   x>0,σ >0

Where SCDF(x, α, β, γ, δ) is the stable distribution function, the distribution function of our LNS mixture distribution becomes:

LNSCDF(x,α,β,γ,σ,δ)=(∫_0^∞)SCDF(x,α,β,s,δ) λ(s,log(γ),σ)ds

Likewise the LNS density is shown below, where SPDF(x, α, β, γ, δ) is the stable density function.

LNSPDF(x,α,β,γ,σ,δ)=(∫_0^∞)SPDF(x,α,β,s,δ) λ(s,log(γ),σ)ds

Note that we have replaced μ with log(γ); as such, γ becomes the median of the lognormally distributed set of (Subscript[Γ, i]) random variables, and it is estimated as the geometric mean of that sample.  The LNS distribution and density functions are degenerate at σ = 0, and we can define them as the SCDF(x, α, β, γ, δ) and SPDF(x, α, β, γ, δ) functions at this parameter point.

Plots of the distribution function with parameters, {α, β, γ, σ, δ}.

Plot[{LNStableCDF[x,1.5,1,1,0.5,0],LNStableCDF[x,1.5,0,1,0.5,0]},{x,-10,10},PerformanceGoal->"Speed",PlotLabel-> "LNS Distribution Function\n{1.5, 1, 1, 0.5, 0} Blue\n{1.5, 0, 1, 0.5, 0} Red" ,Frame->True]

Plots of the LNS and stable density functions with the same parameters, {α, β, γ, (σ), δ}.  The stable functions are in the brighter colors.

Plot[{StablePDF[x,1.5,1,1,0],LNStablePDF[x,1.5,1,1,0.5,0],StablePDF[x,1.5,0,1,0],LNStablePDF[x,1.5,0,1,0.5,0]},{x,-10,10},PerformanceGoal->"Speed",PlotLabel-> "LNS and Stable Density Functions\n{1.5, 1, 1, (0.5), 0} Blue\n{1.5, 0, 1, (0.5), 0} Red",Frame->True,PlotStyle-> {Blue,Darker[Blue],Red,Darker[Red]} ]

Note that the LNS distribution effectively has another shape parameter, σ, which squeezes the distribution in the middle and creates a taller mode.  The symmetric distribution has the taller mode than the skewed distribution in both cases.  A three dimensional plot below shows this concept better, and further shows that the skewness is modified as σ increases.  From the change of shape, as σ increases, it appears that σ will likely be less than 1 for most financial distributions.

Plot3D[LNQkStablePDF[x,1.5,1,1,qs,0],{x,-6,6},{qs,0.1,1},PlotRange->All,PlotPoints->50,AxesLabel-> {"x","σ","density"}]

The tail behavior of the stable and LNS distributions eventually becomes the same as x increases, but the linearity on the log-log plot arises more slowly in the LNS distribution.  The right side of density plots are shown.  The next three plots show the effect of increasing σ.  As σ increases, it takes longer for the log-log linear phase of tail behavior to take hold.

g1=LogLogPlot[{StablePDF[x,1.5,0,1,0],LNStablePDF[x,1.5,0,1,0.5,0]},{x,0.001,15},PerformanceGoal->"Speed"];
Show[g1,Frame->True,PlotLabel-> "Stable Blue\nLNS Red\n{1.5, 0, 1, (0.5), 0}"]

g2=LogLogPlot[{StablePDF[x,1.5,0,1,0],LNStablePDF[x,1.5,0,1,1,0]},{x,0.1,1000},PerformanceGoal->"Speed"];
Show[g2,Frame->True,PlotLabel-> "Stable Blue\nLNS Red\n{1.5, 0, 1, (1), 0}"]

g3=LogLogPlot[{StablePDF[x,1.5,0,1,0],LNStablePDF[x,1.5,0,1,2,0]},{x,0.1,1000000},PerformanceGoal->"Speed"];
Show[g3,Frame->True,PlotLabel-> "Stable Blue\nLNS Red\n{1.5, 0, 1, (2), 0}"]

Here is the heavy tail of the maximally skewed density for the same α, 1.5.

g4=LogLogPlot[{StablePDF[x,1.5,1,1,0],LNStablePDF[x,1.5,1,1,0.5,0]},{x,0.001,15},PerformanceGoal->"Speed",Frame->True,PlotLabel-> "Stable Blue\nLNS Red\n{1.5, 1, 1, (0.5), 0}"]

The light tail of the maximally skewed density shows similar behavior to the stable, but does not decay so rapidly.

g5=LogLogPlot[{StablePDF[x,1.5,-1,1,0],LNStablePDF[x,1.5,-1,1,0.5,0]},{x,0.001,15},PerformanceGoal->"Speed",Frame->True,PlotLabel-> "Stable Blue\nLNS Red\n{1.5, -1, 1, (0.5), 0}"]

We conclude that the tail behavior of the LNS distribution eventually approaches the tail behavior of the stable distribution.  Thus sums of LNS random variables should eventually have a limiting distribution that is a pure stable distribution by the generalized central limit theorem, but this might take sums large numbers of random variables.

In summary, the LNS distribution has another shape parameter, σ, that squeezes the middle of the distribution, causing a higher peak to the mode, and delays the stable tail behavior which occurs further from the mode of the distribution.  Ultimately the distribution is heavy-tailed with the same tail exponent as the stable distribution from which it is derived.

txcolor=RGBColor[181/255,18/255,27/255];
t1 = Graphics[Text[Hyperlink[Framed[Style["Financial Home", {txcolor, Bold, Larger}]], "../map/Overview.html"], {-5, 0}]];
t2 = Graphics[Text[Hyperlink[Framed[Style["Next", {txcolor, Bold, Larger}]],  "../lnn0/LognormalNormal.html"], {0, -0.5}]];
t3 = Graphics[Text[Hyperlink[Framed[Style["Download Notebook", {txcolor, Bold, Larger}]], "../s11/LNSProperties.nb"], {5, 0}]];
t4 = Graphics[Text[Hyperlink[Framed[Style["Previous", {txcolor, Bold, Larger}]], "../s10/LNStableRV.html"], {0, 0.5}]];

Show[ t1, t2, t3,t4, ImageSize -> 500]
CellPrint[TextCell["\n\n© Copyright " <>ToString[DateList[][[1]]]<>" mathestate    "<>DateString[DateList[],"DateShort"], "Text"]]

© Copyright 2009 mathestate    Sat 17 Jan 2009