Double Pareto - Log Normal Distribution

In the last section we derived a normal Laplace distribution as the convolution of the difference of two exponential random variables and a normal random variable.  Next we take the exponent of this random variable to obtain a new distribution that has the same relation to the normal Laplace distribution as the log normal distribution has to the normal distribution.  Thus the density function becomes:

NLPDF[x_, μ_,σ_,α_,β_]:=((α β ((E^((1/2) α (-2 x+2 μ+α (σ^2)))) Erfc[((-x+μ+α (σ^2))/((Sqrt[2]) σ))]+(E^((1/2) β (2 x-2 μ+β (σ^2)))) Erfc[((x-μ+β (σ^2))/((Sqrt[2]) σ))]))/(2 (α+β)));
f=NLPDF[Log[x],μ,σ,α,β]/x;

f(x)=(1/(2 x (α+β)))α β ((e^((1/2) α (α (σ^2)+2 μ-2 log(x)))) erfc(((α (σ^2)+μ-log(x))/((Sqrt[2]) σ)))+(e^((1/2) β (β (σ^2)-2 μ+2 log(x)))) erfc(((β (σ^2)-μ+log(x))/((Sqrt[2]) σ))))

And the distribution function is:

F=Integrate[f,{x,0,t},Assumptions-> {α>0,β>0,σ>0,μ∈Reals,x>0,t>0}]/.t->x;

F(x)=(1/(2 (α+β)))((e^((1/2) β (β (σ^2)-2 μ))) α (erf(-((β (σ^2)-μ+log(x))/((Sqrt[2]) σ)))+1) (x^β)+α erfc(((μ-log(x))/((Sqrt[2]) σ)))+β erfc(((μ-log(x))/((Sqrt[2]) σ)))-(e^((1/2) α (α (σ^2)+2 μ-2 log(x)))) β erfc(((α (σ^2)+μ-log(x))/((Sqrt[2]) σ))))

Random variables can be easily generated by taking the exponent of a normal-Laplace random variable which is the convolution of a normal random variable with the difference of two exponential random variables.

s=Exp[RandomReal[ExponentialDistribution[1],10000]- RandomReal[ExponentialDistribution[2],10000]+RandomReal[NormalDistribution[0,1],10000]];

g1=Plot[NLPDF[Log[x],0,1,1,2]/x,{x,0,10},PlotRange->All,PlotStyle->Thickness[0.008]];
Needs["Histograms`"];
g2=Histogram[s,HistogramScale->1,HistogramRange->{ 0,10}];
Show[g2,g1,PlotLabel-> "Double Pareto-LogNormal Random Variables\nμ = 0, σ = 1\nα = 1.0, β = 2.0"]

The log- log plots of the distribution function for the above parameters show the tails to be log-linear.

LogLogPlot[1-F/.{μ->0,σ->1,α->1,β-> 2},{x,1,1000},PlotLabel->"Log-Log Plot\nRight Tail: 1-F[x]",Frame->True]
LogLogPlot[F/.{μ->0,σ->1,α->1,β-> 2},{x,10^-4,1},PlotLabel->"Log-Log Plot\nLeft Tail: F[x]",Frame->True]

The theoretic importance of the distribution is that it can be derived as the solution to an Itô stochastic integral for geometric Brownian motion.  The full proof is laid out in a paper by William Reed, The Pareto Law of Incomes - an Explanation and an Extension.

We will give only a graphical demonstration.  If you have two independent random variables one distributed log normally and the other exponentially the joint distribution looks like this.

fln=PDF[LogNormalDistribution[μ,σ],x];
fexp= PDF[ExponentialDistribution[λ],t];
fexpln= fln fexp;

f(x,t)=(((e^(-((((log(x)-μ))^2)/(2 (σ^2)))-t λ)) λ)/((Sqrt[2 π]) x σ))

Plot3D[fexpln/.{μ->0,σ->1,λ->1},{x,0,5},{t,0,5},PlotRange->All, PlotLabel-> "Joint LogNormal Exponential Distribution\nμ = 0, σ = 1, λ = 1"]

For simplicity we will consider the case μ = 0.  Now suppose that the Exponential process is stopped at time t  = (σ^2) , the marginal distribution becomes:

fm= Integrate[fexpln D[σ^2,σ]/.{t-> σ^2,μ->0},{σ,0,∞},Assumptions-> {x>0,λ>0}];

fmarg(x)=(((e^(-(Sqrt[2]) (Sqrt[λ]) |log(x)|)) (Sqrt[λ]))/((Sqrt[2]) x))

If we simplify this for x > 1 and 0 < x < 1, we get two distributions with Pareto tails.

CellPrint[ExpressionCell[FullSimplify[fm,x>1],"TraditionalForm"]]
CellPrint[ExpressionCell[FullSimplify[fm,0<x<1],"TraditionalForm"]]

(((x^(-(Sqrt[2]) (Sqrt[λ])-1)) (Sqrt[λ]))/(Sqrt[2]))

(((x^((Sqrt[2]) (Sqrt[λ])-1)) (Sqrt[λ]))/(Sqrt[2]))

In summary the double Pareto - lognormal distribution has power tails and is consistent with a geometric Brownian motion that is generated with time process that is exponentially distributed and stopped.  The general form of this distribution has a random variable that can be generated as the exponent of the sum of a normal random variable with the difference of two exponential random variables.  It appears theoretically an ideal distribution to describe the structure of order books for the continuous double auction model of markets.

txcolor=RGBColor[181/255,18/255,27/255];
t1 = Graphics[Text[Hyperlink[Framed[Style["Financial Home", {txcolor, Bold, Larger}]], "../map/Overview.html"], {-5, 0}]];
t2 = Graphics[Text[Hyperlink[Framed[Style["Next", {txcolor, Bold, Larger}]], "../s07d/CDA2.html"], {0, -0.5}]];
t3 = Graphics[Text[Hyperlink[Framed[Style["Download Notebook", {txcolor, Bold, Larger}]], "../s07c/DoubleParetoLogNormal.nb"], {5, 0}]];
t4 = Graphics[Text[Hyperlink[Framed[Style["Previous", {txcolor, Bold, Larger}]],  "../s07b/Laplace.html"], {0, 0.5}]];
Show[ t1, t2, t3, t4, ImageSize -> 500]
CellPrint[TextCell["\n\n© Copyright " <> ToString[DateList[][[1]]] <> " mathestate    " <> DateString[DateList[], "DateShort"], "Text"]]

© Copyright 2007 mathestate    Sat 29 Dec 2007