Distributions of Returns

We have seen how to calculate returns over some period of time using log prices; but have we have also seen that this approach does not give a very complete description of market behavior.  From now on we will look at log returns or the sequential differences of log prices.  We go back to the whole daily time series.

data= FinancialData["SPY",All];
CellPrint[TextCell["Start ... "<>DateString[First[data][[1]],"Date"],"Text"]]
CellPrint[TextCell["End ... "<>DateString[Last[data][[1]],"Date"],"Text"]]

Start ... Friday 29 January 1993

End ... Friday 26 March 2010

lp= Log[data[[All,2]]];
lr=Differences[lp];
ListPlot[lr,PlotRange->All,Joined-> True, PlotLabel-> "Daily Log Returns, SPY",Frame->True]

We now have a very different picture of what is going on.  There are periods of quiet and periods of wild variation in daily returns.

The density histogram of this series of log returns show that it has a tall peak and heavy tails.  We show the fit to a Normal distribution to this and then ask you to forget about Normal distributions for financial data forever.  The fit is not good, but the real problem is that, events in the tails are greatly underestimated with the Normal assumption.

q1=Histogram[lr,Automatic,"ProbabilityDensity"];
q2=Plot[PDF[NormalDistribution[Mean[lr],StandardDeviation[lr]],x],{x,Min[lr],Max[lr]},PlotStyle->{Red,Thickness[0.005]},PlotRange->All];
Show[q1,q2,Frame->True,PlotRange->All]

Below are the three best and the three worst log returns in series.

up=Take[Sort[lr],-3];
CellPrint[TextCell[ToString[up],"Text"]];
lo=Take[Sort[lr],3];
CellPrint[TextCell[ToString[lo],"Text"]];

{0.0693195, 0.110508, 0.135598}

{-0.10364, -0.0926688, -0.0815945}

Here are the probabilities of the respective occurrences of events better or worse than each of these events as calculated with a Normal distribution.

uppr=Quiet[1-CDF[NormalDistribution[Mean[lr],StandardDeviation[lr]],#]&/@up];
lopr=CDF[NormalDistribution[Mean[lr],StandardDeviation[lr]],#]&/@lo;
CellPrint[TextCell[ToString[AccountingForm[uppr,10]],"Text"]];
CellPrint[TextCell[ToString[AccountingForm[lopr,10]],"Text"]];

{0.0000000159184288, 0., 0.}

{0.00000000000000004096464061, 0.00000000000004692933512, 0.00000000002656838154}

Taking the reciprocals of the probabilities we see how often in trading days we should expect these occurrences along with the length of the time-series at the bottom.

CellPrint[TextCell[ToString[Quiet[Round[1/uppr]]],"Text"]];
CellPrint[TextCell[ToString[Round[1/lopr]],"Text"]];
CellPrint[TextCell[ToString[Length[lr]+1],"Text"]];

{62820270, ComplexInfinity, ComplexInfinity}

{24411296793551652, 21308633447365, 37638724759}

4322

The same results expressed in years; yet over and over we read in the news about how these events should only occur in millions of years--try billions, trillions or even infinity!  Financial returns are not Normally distributed!  We believe that the stable distributions offer a better alternative.

Quiet[CellPrint[TextCell[ToString[AccountingForm[Round[1/uppr]/252.,8,DigitBlock->3]],"Text"]]];
Quiet[CellPrint[TextCell[ToString[AccountingForm[Round[1/lopr]/252.,10,DigitBlock->3]],"Text"]]];
CellPrint[TextCell[ToString[NumberForm[(Length[lr]+1)/252.,4]],"Text"]];

{249,286.79, ComplexInfinity, ComplexInfinity}

{96,870,225,370,000., 84,558,069,240., 149,360,018.9}

17.15

txcolor=RGBColor[181/255,18/255,27/255];
t1 = Graphics[Text[Hyperlink[Framed[Style["Financial Home", {txcolor, Bold, Larger}]], "../map/Overview.html"], {-5, 0}]];
t2 = Graphics[Text[Hyperlink[Framed[Style["Next", {txcolor, Bold, Larger}]],  "../r04/ReturnEvents.html"], {0, -0.5}]];
t3 = Graphics[Text[Hyperlink[Framed[Style["Download Notebook", {txcolor, Bold, Larger}]], "../r03/ReturnDistribution.nb"], {5, 0}]];
t4 = Graphics[Text[Hyperlink[Framed[Style["Previous", {txcolor, Bold, Larger}]], "../r02/MarketReturns.html"], {0, 0.5}]];

Show[ t1, t2, t3,t4, ImageSize -> 500]
CellPrint[TextCell["\n\n© Copyright " <>ToString[DateList[][[1]]]<>" mathestate    "<>DateString[DateList[],"DateShort"], "Text"]]

© Copyright 2010 mathestate    Fri 26 Mar 2010